sphere_radius = 1.0;
circle_radius = 0.1;

ratio = circle_radius / sphere_radius;
d_z = sphere_radius*Sqrt(1 - ratio*ratio);

edge_length = circle_radius / 2.0;

Point(1) = {0, 0, -sphere_radius, edge_length};
Point(2) = {sphere_radius, 0, 0, edge_length};
Point(3) = {sphere_radius*Cos(2*Pi/3), sphere_radius*Sin(2*Pi/3.0), 0, edge_length};
Point(4) = {sphere_radius*Cos(4*Pi/3), sphere_radius*Sin(4*Pi/3.0), 0, edge_length};
Point(5) = {0, 0, 0, edge_length};

Point(6) = {circle_radius, 0, d_z, edge_length};
Point(7) = {circle_radius*Cos(2*Pi/3), circle_radius*Sin(2*Pi/3.0), d_z, edge_length};
Point(8) = {circle_radius*Cos(4*Pi/3), circle_radius*Sin(4*Pi/3.0), d_z, edge_length};
Point(9) = {0, 0, d_z, edge_length};

Circle(1) = {1, 5, 2};
Circle(2) = {1, 5, 3};
Circle(3) = {1, 5, 4};

Circle(4) = {2, 5, 3};
Circle(5) = {3, 5, 4};
Circle(6) = {2, 5, 4};

Circle(7) = {2, 5, 6};
Circle(8) = {3, 5, 7};
Circle(9) = {4, 5, 8};

Circle(10) = {6, 9, 7};
Circle(11) = {7, 9, 8};
Circle(12) = {8, 9, 6};

// lower hemisphere
Line Loop(1) = {1, 6, -3};
Ruled Surface(1) = {1} In Sphere{5};

Line Loop(2) = {3, -5, -2};
Ruled Surface(2) = {2} In Sphere{5};

Line Loop(3) = {2, -4, -1};
Ruled Surface(3) = {3} In Sphere{5};

// upper hemisphere
Line Loop(4) = {-6, 7, -12, -9};
Ruled Surface(4) = {4} In Sphere{5};

Line Loop(5) = {4, 8, -10, -7};
Ruled Surface(5) = {5} In Sphere{5};

Line Loop(6) = {5, 9, -11, -8};
Ruled Surface(6) = {6} In Sphere{5};



