// plaque circulaire de rayon 10 cm

//********************************************** paramètres ********************************
//discrétisation angulaire
nb_arc = 10;

// longueur caractéristique
lc = 0.01;

// decalage tete piston et membrane
decal = 0.001;

// rayon de la tête de piston
R = 0.02;

//*******************************************fin  paramètres ********************************

//************************************* Construction membrane ******************************
// creation du rayon
Point(1) = {0,0,0,lc};
Point(2) = {0.1,0,0,lc};


// ligne
Line(3) = {1,2};
Transfinite Line {3} = 10 Using Progression 1.0;

// extrusion
Extrude Line{3,{0,0,1},{0,0,0},Pi/2} {Recombine; Layers {nb_arc,1};};
Extrude Line{4,{0,0,1},{0,0,0},Pi/2} {Recombine; Layers {nb_arc,1};};

//**********************************fin  Construction membrane ******************************

//************************************* Construction piston ******************************
Point(7) = {0,0,decal,lc};
Point(8) = {0,0,decal+R,lc};

// ligne
Line(9) = {7,8};
Transfinite Line {9} = 10 Using Progression 1.0;

// extrusion
Extrude Line{9,{0,1,0},{0,0,decal+R},-Pi/2} {Recombine; Layers {nb_arc,1};};
Extrude Surface{12,{0,0,1},{0,0,decal+R},Pi/2} {Recombine; Layers {nb_arc,1};};
Extrude Surface{24,{0,0,1},{0,0,decal+R},Pi/2} {Recombine; Layers {nb_arc,1};};
Coherence;

//**********************************fin  Construction piston******************************



//************************************* Entités physiques ***********************************

// membrane
plaque = 666;
Physical Surface(plaque) = {6,9};

contour = 67;
Physical Line(contour) = {5,8};

bord = 68;
Physical Line(bord) = {3,7};

// tete de piston
piston = 777;
Physical Volume(piston) = {1,2};

surf_ct = 78;
Physical Surface(surf_ct)={22,34};


//********************************** Fin Entités physiques ***********************************




